#import "QtChildEvent.h"
#import "QtObject.h"

@implementation QtChildEvent
- initWithQEvent: (QEvent*)event
{
	OF_INVALID_INIT_METHOD
}

- initWithQChildEvent: (QChildEvent*)event
{
	return [super initWithQEvent: event];
}

- initWithType: (QChildEvent::Type)type
	 child: (QtObject*)child
{
	try {
		return [self initWithQChildEvent:
		    new QChildEvent(type, [child qObject])];
	} catch (const std::bad_alloc &e) {
		self = [super initWithQEvent: NULL];
		[self release];
		throw;
	}
}

- (QChildEvent*)qChildEvent
{
	return dynamic_cast<QChildEvent*>(_qEvent);
}

- (bool)isAdded
{
	return [self qChildEvent]->added();
}

- (QtObject*)child
{
	return [[[QtObject alloc]
	    initWithQObject: [self qChildEvent]->child()] autorelease];
}

- (bool)isPolished
{
	return [self qChildEvent]->polished();
}

- (bool)isRemoved
{
	return [self qChildEvent]->removed();
}
@end
<p class="generalError">
SQLITE_FULL(13): statement aborts at 27: [REPLACE INTO config(name,value,mtime)VALUES(&#39;baseurl:https://fl.nil.im/objqt&#39;,1,now())] database or disk is full
SQL: REPLACE INTO config(name,value,mtime)VALUES(&#39;baseurl:https://fl.nil.im/objqt&#39;,1,now())
</p>
