ObjMatrix  Artifact [5214b84937]

Artifact 5214b849377e53defe773e386d03a047e5a2ba2ed8ea02328fe7554ec4ca31ab:

• File meson.build — part of check-in [3f21e45c11] at 2024-08-17 00:34:03 on branch trunk — Include includedir in .oc file (user: js, size: 717) [annotate] [blame] [check-ins using]

project('ObjMatrix', 'objc',
  version: '0.1',
  meson_version: '>= 1.5.0',
  default_options: {
    'b_asneeded': 'false',
    'warning_level': '3',
  })

objfw_dep = dependency('objfw', modules: ['ObjFWTLS', 'ObjSQLite3'])

incdir = include_directories('src', 'src/exceptions')

subdir('src')
subdir('tests')

objfwconfig = find_program('objfw-config')
packages_dir = run_command(
  [objfwconfig, '--packages-dir'],
  check: true).stdout().strip()

configure_file(
  input: 'ObjMatrix.oc.in',
  output: 'ObjMatrix.oc',
  configuration: {
    'includedir': get_option('prefix') / get_option('includedir'),
    'libdir': get_option('prefix') / get_option('libdir'),
  },
  install: true,
  install_dir: packages_dir)