configs  Check-in [bed5a23ae3]

function fgrep
    if type -q ggrep
        command ggrep -F --color=auto $argv
    else
        command fgrep --color=auto $argv
    end
end

function fish_prompt --description 'Write out the prompt'
    set -l suffix
    switch "$USER"
        case root toor
            set suffix (set_color $fish_color_cwd_root)'#'
        case '*'
            set suffix '>'
    end

    set -l branch (git symbolic-ref HEAD 2>/dev/null)
    set branch (string replace -r "^refs/heads/" "" $branch)
    set -l vcs
    if test -n "$branch" -a "$branch" != "master"
        set vcs (set_color $fish_color_vcs_braces)"(" \
                (set_color $fish_color_vcs)"$branch" \
                (set_color $fish_color_vcs_braces)")"
    end

    echo -n -s (set_color $fish_color_host) (prompt_hostname) ' ' \
               (set_color $fish_color_cwd) (prompt_pwd) (string join '' $vcs) \
               (set_color $fish_color_suffix) $suffix (set_color normal) ' '
end

function fish_right_prompt
    set -l code $status
    set -l jobs (jobs | wc -l)
    set -l prompt

    test $jobs -gt 0
    and set -a prompt (set_color $fish_color_jobs)$jobs

    test $code -gt 0
    and set -a prompt (set_color $fish_color_status)$code

    echo $prompt

    set_color normal
end

function fish_title
    echo (status current-command) · (prompt_pwd) · (prompt_hostname)
end

function gpg-sftp
    set -lx SSH_AUTH_SOCK $HOME/.gnupg/S.gpg-agent.ssh
    sftp $argv
end

function gpg-ssh-add
    set -lx SSH_AUTH_SOCK $HOME/.gnupg/S.gpg-agent.ssh
    ssh-add $argv
end

function gpg-ssh
    set -lx SSH_AUTH_SOCK $HOME/.gnupg/S.gpg-agent.ssh
    ssh $argv
end

function grep
    if type -q ggrep
        command ggrep --color=auto $argv
    else
        command grep --color=auto $argv
    end
end

function ixio
    curl -F 'f:1=<-' ix.io
end

function ls --description 'List contents of directory'
    if type -q gls
        command gls --color=auto $argv
    else
        command ls --color=auto $argv
    end
end

# Automatically use bmake instead of make when using pkgsrc, if necessary
function make
    if string match -q -r '/pkgsrc$|/pkgsrc/' $PWD
        # pkgsrc does not like MAKEFLAGS including -j
        set -lx MAKEFLAGS

        if type -q bmake
            command bmake $argv
        else
            command make $argv
        end
    else
        command make $argv
    end
end

# To work around mpv not liking locales that use , as a decimal separator
function mpv
    set -lx LC_ALL C
    command mpv $argv
end

function pkg_chk
    set -lx MAKEFLAGS
    command pkg_chk $argv
end

function pkg_rolling-replace
    set -lx MAKEFLAGS
    command pkg_rolling-replace $argv
end

function prompt_pwd --description 'Print the current working directory'
    set -l options 'h/help'
    argparse -n prompt_pwd --max-args=0 $options -- $argv
    or return

    if set -q _flag_help
        __fish_print_help prompt_pwd
        return 0
    end

    # Replace $HOME with "~"
    set realhome ~
    set -l tmp (basename (string replace -r '^'"$realhome"'($|/)' '~$1' $PWD))


    test $PWD = "/$tmp"
    and set tmp $PWD

    echo $tmp
end

function pw
    set -l clipboard
    if type -q pbcopy
        set clipboard pbcopy
    else if type -q xclip
        set clipboard xclip
    else
        echo "No clipboard handler found!"
        return 1
    end

    cryptopassphrase -k ~/.scrypt-pwgen.key $argv | tr -d '\n' | $clipboard
end

function pws
    set -l clipboard
    if type -q pbcopy
        set clipboard pbcopy
    else if type -q xclip
        set clipboard xclip
    else
        echo "No clipboard handler found!"
        return 1
    end

    cryptopassphrase -k ~/.scrypt-pwgen-server.key $argv \
        | tr -d '\n' | $clipboard
end

# pkgsrc does not like MAKEFLAGS being set
function url2pkg
    set -lx MAKEFLAGS
    command url2pkg $argv
end