configs  Artifact [9b3d902cb4]

Artifact 9b3d902cb496233d186fe707f80c992d1b254079bc2da09181c04fb81f5a00ef:

• File config/fish/functions/fish_prompt.fish — part of check-in [bed5a23ae3] at 2020-02-19 21:46:19 on branch trunk — Consistent indenting for .fish files (user: js size: 813)
• File fish/functions/fish_prompt.fish — part of check-in [24d2eb82f0] at 2020-02-20 22:07:34 on branch trunk — Remove useless config subdirectory (user: js size: 813)

function fish_prompt --description 'Write out the prompt'
    set -l suffix
    switch "$USER"
        case root toor
            set suffix (set_color $fish_color_cwd_root)'#'
        case '*'
            set suffix '>'
    end

    set -l branch (git symbolic-ref HEAD 2>/dev/null)
    set branch (string replace -r "^refs/heads/" "" $branch)
    set -l vcs
    if test -n "$branch" -a "$branch" != "master"
        set vcs (set_color $fish_color_vcs_braces)"(" \
                (set_color $fish_color_vcs)"$branch" \
                (set_color $fish_color_vcs_braces)")"
    end

    echo -n -s (set_color $fish_color_host) (prompt_hostname) ' ' \
               (set_color $fish_color_cwd) (prompt_pwd) (string join '' $vcs) \
               (set_color $fish_color_suffix) $suffix (set_color normal) ' '
end