export EDITOR="vim"
export PAGER="less"
export LS_COLORS='di=34:ow=44;37:tw=44;37:st=44;37:ex=31:su=7;31:sg=7;31:ln=33:or=7;33:pi=32:do=32:bd=35:cd=35:so=32:*.bz2=36:*.dmg=36:*.gz=36:*.gpg=36:*.rar=36:*.tar=36:*.tbz2=36:*.tgz=36:*.xz=36:*.zip=36:*.orig=90:*~=90'
LISTMAX=32768
WORDCHARS="*?[];!#~"
local grep=""
local grep_color="auto"
local ls=""
local ls_color="auto"
local ls_on_cd="yes"
local ls_on_init="no"
bindkey -v
# history-incremental-search-backward is much more useful than
# _history-complete-*
bindkey "^R" history-incremental-search-backward
# Add a few other emacs bindings for convenience, as it's sometimes quicker to
# use those than to switch between modes.
bindkey "^A" beginning-of-line
bindkey "^E" end-of-line
bindkey "^D" delete-char-or-list
# backward-kill-word behaves more like vim, whereas vi-backward-kill-word is
# the vi behaviour.
bindkey "^W" backward-kill-word
setopt no_bg_nice
setopt no_nomatch
setopt extended_glob
setopt autocd
setopt auto_pushd
autoload -U compinit
compinit -C
# Ignore case on completion
zstyle ':completion:*' matcher-list 'm:{A-Z}={a-z} m:{a-z}={A-Z}'
__find_command() {
which "$1" &>/dev/null && echo "$1" || echo "$2"
}
if [ -n "$grep" -o -n "$grep_color" ]; then
: ${grep:=$(__find_command ggrep grep)}
[ -n "$grep_color" -a "$grep_color[1]" != - ] &&
grep_color="--color=$grep_color"
alias grep="$grep $grep_color"
fi
alias fgrep="grep -F"
if [ -n "$ls" -o -n "$ls_color" ]; then
: ${ls:=$(__find_command gls ls)}
[ -n "$ls_color" -a "$ls_color[1]" != - ] &&
ls_color="--color=$ls_color"
alias ls="$ls $ls_color"
fi
[ "$ls_on_cd" = yes ] && chpwd() { ls }
[ "$ls_on_init" = yes ] && ls
case $TERM_PROGRAM in
Apple_Terminal)
__update_terminal_cwd() {
printf '\e]7;%s\a' "file://$HOSTNAME${PWD// /%20}"
}
;;
*)
__update_terminal_cwd() {}
;;
esac
__color() { print "%{\e[$1m%}" }
__color_256() { __color "38;5;$1" }
__reset_color() { __color 0 }
set_prompt() {
PS1="$(__color_256 23)%m "
PS1+="$(__color_256 29)%c"
PS1+="$@$(__color_256 36)%B%(!.#.>)$(__reset_color) "
PS2="%B>%b "
RPS1="%(1j.$(__color "1;33")%j$(__reset_color).)"
RPS1+="%(?..%(1j. .)$(__color "1;31")%?$(__reset_color))"
RPS2="%(1_.$(__color "1;30")(%_%)$(__reset_color).)"
}
set_prompt
__precmd() {
__update_terminal_cwd
local branch_name=$(git symbolic-ref HEAD 2>/dev/null)
branch_name=${branch_name##refs/heads/}
if [ -n "$branch_name" -a "$branch_name" != master ]; then
local branch="$(__color_256 36)($(__color_256 78)$branch_name"
branch+="$(__color_256 36))"
fi
set_prompt $branch
}
case $TERM in
aterm|Eterm|rxvt*|uxterm*|xterm*)
# Use set_title if you want to change the term title
set_title() {
# Without this, precmd would override it
precmd() { __precmd }
print -Pn "\e]0;$@\a"
}
unset_title() {
precmd() {
print -Pn "\e]0;%m:%c\a"
__precmd
}
}
unset_title
;;
*)
precmd() { __precmd }
;;
esac
extr() {
for i in $@; do
case $i in
*.7z)
7za x $i
;;
*.lha)
ofarc -x $i
;;
*.tar)
ofarc -x $i
;;
*.tbz | *.tbz2 | *.tar.bz2)
bzcat $i | ofarc -ttar -x -
;;
*.tgz | *.tar.gz)
ofarc -x $i
;;
*.txz | *.tar.xz)
xzcat $i | ofarc -ttar -x -
;;
*.rar)
unrar x $i
;;
*.zip)
ofarc -x $i
;;
# These have to be the last for obvious reasons
*.bz2)
bunzip2 $i
;;
*.gz)
ofarc -x $i
;;
*.xz)
unxz $i
;;
*)
echo "$i: Unknown file type"
false
;;
esac
done
}
for ext in 7z lha tar tbz tbz2 tar.bz2 tgz tar.gz txz tar.xz rar zip bz2 gz xz
do
alias -s "$ext=extr"
done
[ "$EDITOR" = vim ] && alias vi=vim
which gpg2 &>/dev/null && alias gpg=gpg2
make() {
case "$PWD" in
# pkgsrc needs bmake and does not like MAKEFLAGS including -j.
*/pkgsrc | */pkgsrc/*)
MAKEFLAGS= =$(__find_command bmake make) $@
;;
*)
=make $@
;;
esac
}
# pkgsrc does not like MAKEFLAGS including -j
which pkg_chk &>/dev/null && alias pkg_chk="MAKEFLAGS= pkg_chk"
which pkg_rolling-replace &>/dev/null &&
alias pkg_rolling-replace="MAKEFLAGS= pkg_rolling-replace"
which url2pkg &>/dev/null && alias url2pkg="MAKEFLAGS= url2pkg"
alias gpg-ssh="SSH_AUTH_SOCK=$HOME/.gnupg/S.gpg-agent.ssh ssh"
alias gpg-ssh-add="SSH_AUTH_SOCK=$HOME/.gnupg/S.gpg-agent.ssh ssh-add"
alias gpg-sftp="SSH_AUTH_SOCK=$HOME/.gnupg/S.gpg-agent.ssh sftp"
__pw() {
local clipboard
if which pbcopy &>/dev/null; then
clipboard=pbcopy
elif which xclip &>/dev/null; then
clipboard=xclip
else
echo "No clipboard handler found!"
return 1
fi
cryptopassphrase $@ | tr -d '\n' | $clipboard
}
alias pw="__pw -k ~/.cryptopassphrase.key"
alias pws="__pw -k ~/.cryptopassphrase-server.key"
ixio() { curl -F 'f:1=<-' ix.io }
0x0st() { curl -F'file=@-' https://0x0.st }
unset fgrep grep grep_color ls ls_color ls_on_cd ls_on_init
unset HISTFILE