configs  Artifact [7fb3140ed6]

Artifact 7fb3140ed6aa6c3e083ab85187b26fc5e2655333231772656cc5adb35ae634eb:

• File fish/functions/fish_prompt.fish — part of check-in [aed8907a52] at 2020-05-24 20:51:51 on branch trunk — Add Fossil branch to fish prompt

  Also prefer Git over Fossil branch instead of showing both in zsh. (user: js, size: 870) [annotate] [blame] [check-ins using]

function fish_prompt --description 'Write out the prompt'
    set -l suffix
    switch "$USER"
        case root toor
            set suffix (set_color $fish_color_cwd_root)'#'
        case '*'
            set suffix '>'
    end

    set -l branch (git symbolic-ref HEAD 2>/dev/null)
    set branch (string replace -r "^refs/heads/" "" $branch)
    
    if test -z "$branch"
        set branch (fossil branch current)
    end

    set -l vcs
    if test -n "$branch"
        set vcs (set_color $fish_color_vcs_braces)"(" \
                (set_color $fish_color_vcs)"$branch" \
                (set_color $fish_color_vcs_braces)")"
    end

    echo -n -s (set_color $fish_color_host) (prompt_hostname) ' ' \
               (set_color $fish_color_cwd) (prompt_pwd) (string join '' $vcs) \
               (set_color $fish_color_suffix) $suffix (set_color normal) ' '
end